【VBA】乱数生成のロジック（メカニズム）といろいろな乱数処理の方法

Function rand()
    Randomize
    Debug.Print Rnd
    '>> 0.495711
End Function

Function get_Random(times_, min_, max_)
    Dim i As Long
    Dim arrs() As Variant
    If min_ > max_ Then
        MsgBox ("最小値 ＞ 最大値になっています。")
        get_Random = Array()
        Exit Function
    End If
    Randomize
    For i = 1 To times_
        ReDim Preserve arrs(i - 1)
        arrs(i - 1) = Int((max_ - min_ + 1) * Rnd + min_)
    Next i
    get_Random = arrs
End Function

Function get_unique_Random(times_, min_, max_)
    Dim i As Long
    Dim arr, arrs() As Variant
    Dim rndNum As Long
    Dim fil_arr As Variant
    Dim flg As Boolean
    
    '最大値＞最小値で入力してもらいたいため
    If min_ > max_ Then
        MsgBox ("最小値 ＞ 最大値になっています。")
        get_unique_Random = Array()
        Exit Function
    End If
    
    'エラー回避　一度使った数値は使えないので、反復のほうが多いと無限ループになる。
    If max_ - min_ + 1 < times_ Then
        MsgBox ("重複なしを作るには反復回数が多すぎます。設定を確認してください")
        get_unique_Random = Array()
        Exit Function
    End If
    
    Randomize
    For i = 1 To times_
        ReDim Preserve arrs(i - 1)
        
        '乱数を取得。その際、重複がある場合は乱数を取り直す。
        Do
            rndNum = Int((max_ - min_ + 1) * Rnd + min_)
            
            '配列内をfor文で要素を取り出し、完全一致するものがあるかどうか判定
            '完全一致する⇒flg=Trueとなり、もう一度乱数を取り直す。
            flg = False
            For Each arr In arrs
                If rndNum = arr Then
                    flg = True
                    Exit For
                End If
            Next
        Loop While flg = True
        arrs(i - 1) = rndNum
    Next i
    get_unique_Random = arrs
    
End Function

Function get_Random_date(times_, start_date, end_date)
    Dim rndNum As Long '乱数
    Dim date_Diff As Long '日付の差分
    Dim arrs() As Variant '乱数を格納する配列
    Dim i As Long 'for文で使用するインデックス数値
    
    '逆だと値がおかしくなるため
    If start_date > end_date Then
        MsgBox ("開始日 ＞ 終了日になっています。")
        get_Random_date = Array()
        Exit Function
    End If
    
    'start_dateとend_dateの差分
    date_Diff = DateDiff("d", start_date, end_date)
    
    Randomize
    For i = 1 To times_
        ReDim Preserve arrs(i - 1)
        rndNum = Int((date_Diff + 1) * Rnd) '乱数生成
        '開始日に生成した乱数分を足す
        arrs(i - 1) = DateAdd("d", rndNum, start_date)
    Next i
    get_Random_date = arrs
End Function

Function get_unique_Random_date(times_, start_date, end_date)
    Dim rndNum As Long '乱数
    Dim rndDate As Date '開始日に乱数分足した日数
    Dim date_Diff As Long '日付の差分
    Dim arr, arrs() As Variant '乱数を格納する配列
    Dim i As Long 'for文で使用するインデックス数値
    Dim flg As Boolean '配列内に重複する要素があるかどうかブール型で取得
    
    '逆だと値がおかしくなるため
    If start_date > end_date Then
        MsgBox ("開始日 ＞ 終了日になっています。")
        get_unique_Random_date = Array()
        Exit Function
    End If
    
    'start_dateとend_dateの差分
    date_Diff = DateDiff("d", start_date, end_date)
    
    'エラー回避　一度使った数値は使えないので、反復のほうが多いと無限ループになる。
    If date_Diff + 1 < times_ Then
        MsgBox ("重複なしを作るには反復回数が多すぎます。設定を確認してください")
        get_unique_Random_date = Array()
        Exit Function
    End If
    
    Randomize
    For i = 1 To times_
        ReDim Preserve arrs(i - 1)

        '乱数を取得。その際、重複がある場合は乱数を取り直す。
        Do
            rndNum = Int((date_Diff + 1) * Rnd) '乱数生成
            rndDate = DateAdd("d", rndNum, start_date) '開始日に乱数分足す
            
            '配列内をfor文で要素を取り出し、完全一致するものがあるかどうか判定
            '完全一致する⇒flg=Trueとなり、もう一度乱数を取り直す。
            flg = False
            For Each arr In arrs
                If rndDate = arr Then
                    flg = True
                    Exit For
                End If
            Next
        Loop While flg = True
        arrs(i - 1) = rndDate
    Next i
    get_unique_Random_date = arrs
End Function