【VBA】データ保存場所自動管理。指定フォルダ内に年（もしくは年度）と月のフォルダを作成する関数

Function create_YearMonth_Dir(ByVal file_Dir As String, ByVal date_ As Date, ByVal fiscalYear As Boolean)
    '年（もしくは年度）、月を取得
    Dim Year_str, Month_str As String
    
    'fiscalYear=True→年度
    If fiscalYear Then
    
        '月が1～3月→　年-1＝年度
        If Month(date_) <= 3 Then
            Year_str = Year(date_) - 1 & "年度"
            
        '月が４月～　→　年＝年度
        Else
            Year_str = Year(date_) & "年度"
        End If
        
    'fiscalYear=False→年
    Else
        Year_str = Year(date_) & "年"
    End If
    
    '月はいつでもそのまま
    Month_str = Month(date_) & "月"
        
    
    'フォルダ作成
    Dim create_Dir As String
    Dim FSO As Object
    Set FSO = CreateObject("Scripting.FilesystemObject")
    
    '年（もしくは年度）のフォルダがあるかどうか
    create_Dir = file_Dir & "\" & Year_str
    If Dir(create_Dir, vbDirectory) = "" Then
        FSO.CreateFolder (create_Dir)
    End If
    
    '月フォルダがあるかどうか
    create_Dir = create_Dir & "\" & Month_str
    If Dir(create_Dir, vbDirectory) = "" Then
        FSO.CreateFolder (create_Dir)
    End If
    
    create_YearMonth_Dir = create_Dir
    
End Function

Sub test_create()
    Dim file_Dir, result As String
    Dim date_ As Date
    Dim fiscalYear As Boolean
    
    '日付はDate型で指定。当日の日付で常に運用するなら「Date」関数を使うと良い。
    date_ = #3/1/2023#
    
    'フォルダを作成する場所を指定する
    file_Dir = ThisWorkbook.Path & "\test"
    
    '年度か年かどちらでフォルダを作るか指定 True＝年度、False＝年
    fiscalYear = True
    
    result = create_YearMonth_Dir(file_Dir, date_, fiscalYear)
    Debug.Print result
    '>> thisworbook.path以降は　→　..\test\2022年度\3月
End Sub